home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / langs / clisp-c.zoo / macros2.lsp < prev    next >
Encoding:
Text File  |  1993-06-05  |  14.3 KB  |  348 lines
  1. (in-package "SYSTEM")
  2. ;-------------------------------------------------------------------------------
  3. (defmacro typecase (keyform &rest typeclauselist)
  4.   (let* ((tempvar (gensym))
  5.          (condclauselist nil))
  6.     (do ((typeclauselistr typeclauselist (cdr typeclauselistr)))
  7.         ((atom typeclauselistr))
  8.       (cond ((atom (car typeclauselistr))
  9.              (error #+DEUTSCH "Unzulässige Klausel in ~S: ~S"
  10.                     #+ENGLISH "Invalid clause in ~S: ~S"
  11.                     #+FRANCAIS "Clause inadmissible dans ~S : ~S"
  12.                     'typecase (car typeclauselistr)
  13.             ))
  14.             ((let ((type (caar typeclauselistr)))
  15.                (or (eq type T) (eq type 'OTHERWISE))
  16.              )
  17.              (push `(T ,@(or (cdar typeclauselistr) '(NIL))) condclauselist)
  18.              (return)
  19.             )
  20.             (t (push `((TYPEP ,tempvar (QUOTE ,(caar typeclauselistr)))
  21.                        ,@(or (cdar typeclauselistr) '(NIL))
  22.                       )
  23.                      condclauselist
  24.             )  )
  25.     ) )
  26.     `(LET ((,tempvar ,keyform)) (COND ,@(nreverse condclauselist)))
  27. ) )
  28. ;-------------------------------------------------------------------------------
  29. (defmacro check-type (place typespec &optional (string nil))
  30.   (let ((tag1 (gensym))
  31.         (tag2 (gensym)))
  32.     `(TAGBODY
  33.        ,tag1
  34.        (WHEN (TYPEP ,place ',typespec) (GO ,tag2))
  35.        (CERROR #+DEUTSCH "Sie dürfen einen neuen Wert eingeben."
  36.                #+ENGLISH "You may input a new value."
  37.                #+FRANCAIS "Vous avez l'occasion d'entrer une nouvelle valeur."
  38.          #+DEUTSCH "~A~%Der Wert ist: ~S"
  39.          #+ENGLISH "~A~%The value is: ~S"
  40.          #+FRANCAIS "~A~%La valeur est : ~S"
  41.          ,(format nil #+DEUTSCH "Der Wert von ~S sollte ~:[vom Typ ~S~;~:*~A~] sein."
  42.                       #+ENGLISH "The value of ~S should be ~:[of type ~S~;~:*~A~]."
  43.                       #+FRANCAIS "La valeur de ~S devrait être ~:[de type ~S~;~:*~A~]."
  44.                       place string typespec
  45.           )
  46.          ,place
  47.        )
  48.        (WRITE-STRING
  49.          ,(format nil #+DEUTSCH "~%Neues ~S: "
  50.                       #+ENGLISH "~%New ~S: "
  51.                       #+FRANCAIS "~%Nouveau ~S : "
  52.                       place
  53.           )
  54.          *QUERY-IO*
  55.        )
  56.        (SETF ,place (READ *QUERY-IO*))
  57.        (GO ,tag1)
  58.        ,tag2
  59.      )
  60. ) )
  61. ;-------------------------------------------------------------------------------
  62. (defmacro assert (test-form &optional (place-list nil) (string nil) &rest args)
  63.   (let ((tag1 (gensym))
  64.         (tag2 (gensym)))
  65.     `(TAGBODY
  66.        ,tag1
  67.        (WHEN ,test-form (GO ,tag2))
  68.        (CERROR ,(case (length place-list)
  69.                   (0 #+DEUTSCH "Neuer Anlauf"
  70.                      #+ENGLISH "Retry"
  71.                      #+FRANCAIS "Reéssayer"
  72.                   )
  73.                   (1 #+DEUTSCH "Sie dürfen einen neuen Wert eingeben."
  74.                      #+ENGLISH "You may input a new value."
  75.                      #+FRANCAIS "Vous pouvez entrer une nouvelle valeur."
  76.                   )
  77.                   (t #+DEUTSCH "Sie dürfen neue Werte eingeben."
  78.                      #+ENGLISH "You may input new values."
  79.                      #+FRANCAIS "Vous pouvez entrer de nouvelles valeurs."
  80.                 ) )
  81.                ',(or string "~A")
  82.                ,@(if string
  83.                    args
  84.                    (list (format nil #+DEUTSCH "Der Wert von ~S darf nicht NIL sein."
  85.                                      #+ENGLISH "~S must evaluate to a non-NIL value."
  86.                                      #+FRANCAIS "La valeur de ~S ne peut pas être NIL."
  87.                                      test-form
  88.                  ) )     )
  89.        )
  90.        ,@(mapcan
  91.            #'(lambda (place)
  92.                (list `(WRITE-STRING
  93.                         ,(format nil #+DEUTSCH "~%Neues ~S: "
  94.                                      #+ENGLISH "~%New ~S: "
  95.                                      #+FRANCAIS "~%Nouveau ~S : "
  96.                                      place
  97.                          )
  98.                         *QUERY-IO*
  99.                       )
  100.                      `(SETF ,place (READ *QUERY-IO*))
  101.              ) )
  102.            place-list
  103.          )
  104.        (GO ,tag1)
  105.        ,tag2
  106.      )
  107. ) )
  108. ;-------------------------------------------------------------------------------
  109. (flet ((typecase-errorstring (keyform keyclauselist)
  110.          (format nil #+DEUTSCH "Der Wert von ~S muß einem der Typen ~{~S~^, ~} angehören."
  111.                      #+ENGLISH "The value of ~S must be of one of the types ~{~S~^, ~}"
  112.                      #+FRANCAIS "La valeur de ~S doit appartenir à l'un des types ~{~S~^, ~}."
  113.                      keyform (mapcar #'first keyclauselist)
  114.        ) )
  115.        (case-errorstring (keyform keyclauselist)
  116.          (format nil #+DEUTSCH "Der Wert von ~S muß einer der folgenden sein: ~{~S~^, ~}"
  117.                      #+ENGLISH "The value of ~S must be one of ~{~S~^, ~}"
  118.                      #+FRANCAIS "La valeur de ~S doit être l'une des suivantes : ~{~S~^, ~}"
  119.                      keyform
  120.                      (mapcap #'(lambda (keyclause)
  121.                                  (setq keyclause (car keyclause))
  122.                                  (if (listp keyclause) keyclause (list keyclause))
  123.                                )
  124.                              keyclauselist
  125.        ) )           )
  126.        (simple-error (casename form clauselist errorstring)
  127.          (let ((var (gensym)))
  128.            `(LET ((,var ,form))
  129.               (,casename ,var
  130.                 ,@clauselist
  131.                 (OTHERWISE
  132.                   (ERROR #+DEUTSCH "~A~%Der Wert ist: ~S"
  133.                          #+ENGLISH "~A~%The value is: ~S"
  134.                          #+FRANCAIS "~A~%La valeur est : ~S"
  135.                          ,errorstring ,var
  136.             ) ) ) )
  137.        ) )
  138.        (retry-loop (casename place clauselist errorstring)
  139.          (let ((g (gensym))
  140.                (h (gensym)))
  141.            `(BLOCK ,g
  142.               (TAGBODY
  143.                 ,h
  144.                 (RETURN-FROM ,g
  145.                   (,casename ,place
  146.                     ,@clauselist
  147.                     (OTHERWISE
  148.                       (CERROR #+DEUTSCH "Sie dürfen einen neuen Wert eingeben."
  149.                               #+ENGLISH "You may input a new value."
  150.                               #+FRANCAIS "Vous pouvez entrer une nouvelle valeur."
  151.                               #+DEUTSCH "~A~%Der Wert ist: ~S"
  152.                               #+ENGLISH "~A~%The value is: ~S"
  153.                               #+FRANCAIS "~A~%La valeur est : ~S"
  154.                               ,errorstring
  155.                               ,place
  156.                       )
  157.                       (WRITE-STRING
  158.                         ,(format nil #+DEUTSCH "~%Neues ~S: "
  159.                                      #+ENGLISH "~%New ~S: "
  160.                                      #+FRANCAIS "~%Nouveau ~S : "
  161.                                      place
  162.                          )
  163.                         *QUERY-IO*
  164.                       )
  165.                       (SETF ,place (READ *QUERY-IO*))
  166.                       (GO ,h)
  167.             ) ) ) ) )
  168.       )) )
  169.   (defmacro etypecase (keyform &rest keyclauselist)
  170.     (simple-error 'TYPECASE keyform keyclauselist
  171.                   (typecase-errorstring keyform keyclauselist)
  172.   ) )
  173.   (defmacro ctypecase (keyplace &rest keyclauselist)
  174.     (retry-loop 'TYPECASE keyplace keyclauselist
  175.                 (typecase-errorstring keyplace keyclauselist)
  176.   ) )
  177.   (defmacro ecase (keyform &rest keyclauselist)
  178.     (simple-error 'CASE keyform keyclauselist
  179.                   (case-errorstring keyform keyclauselist)
  180.   ) )
  181.   (defmacro ccase (keyform &rest keyclauselist)
  182.     (retry-loop 'CASE keyform keyclauselist
  183.                 (case-errorstring keyform keyclauselist)
  184.   ) )
  185. )
  186. ;-------------------------------------------------------------------------------
  187. (defmacro deftype (name lambdalist &body body &environment env)
  188.   (unless (symbolp name)
  189.     (error #+DEUTSCH "Typname muß ein Symbol sein, nicht ~S"
  190.            #+ENGLISH "type name should be a symbol, not ~S"
  191.            #+FRANCAIS "Le type doit être un symbole et non ~S"
  192.            name
  193.   ) )
  194.   (if (or (get name 'TYPE-SYMBOL) (get name 'TYPE-LIST))
  195.     (error #+DEUTSCH "~S ist ein eingebauter Typ und darf nicht umdefiniert werden."
  196.            #+ENGLISH "~S is a built-in type and may not be redefined."
  197.            #+FRANCAIS "~S est un type prédéfini et ne peut pas être redéfini."
  198.            name
  199.   ) )
  200.   (multiple-value-bind (body-rest declarations docstring)
  201.       (SYSTEM::PARSE-BODY body t env)
  202.     (if declarations (setq declarations (list (cons 'DECLARE declarations))))
  203.     (let ((%arg-count 0) (%min-args 0) (%restp nil)
  204.           (%let-list nil) (%keyword-tests nil) (%default-form '(QUOTE *)))
  205.       (analyze1 lambdalist '(CDR <DEFTYPE-FORM>) name '<DEFTYPE-FORM>)
  206.       (let ((lengthtest (make-length-test '<DEFTYPE-FORM>))
  207.             (mainform `(LET* ,(nreverse %let-list)
  208.                          ,@declarations
  209.                          ,@(nreverse %keyword-tests)
  210.                          ,@body-rest
  211.            ))          )
  212.         (if lengthtest
  213.           (setq mainform
  214.             `(IF ,lengthtest
  215.                (ERROR #+DEUTSCH "Der Deftype-Expander für ~S kann nicht mit ~S Argumenten aufgerufen werden."
  216.                       #+ENGLISH "The deftype expander for ~S may not be called with ~S arguments."
  217.                       #+FRANCAIS "L'«expandeur» de DEFTYPE pour ~S ne peut pas être appelé avec ~S arguments."
  218.                       ',name (1- (LENGTH <DEFTYPE-FORM>))
  219.                )
  220.                ,mainform
  221.         ) )  )
  222.         `(EVAL-WHEN (COMPILE LOAD EVAL)
  223.            (%PUT ',name 'DEFTYPE-EXPANDER
  224.              (FUNCTION ,(make-symbol (string-concat "DEFTYPE-" (string name)))
  225.                (LAMBDA (<DEFTYPE-FORM>) ,mainform)
  226.            ) )
  227.            (SETF (DOCUMENTATION ',name 'TYPE) ',docstring)
  228.            ',name
  229.          )
  230. ) ) ) )
  231. ;-------------------------------------------------------------------------------
  232. (defmacro time (form)
  233.   (let ((vars (list (gensym) (gensym) (gensym) (gensym) (gensym) (gensym)
  234.                     (gensym) (gensym) (gensym)
  235.        ))     )
  236.     `(MULTIPLE-VALUE-BIND ,vars (%%TIME)
  237.        (UNWIND-PROTECT ,form (MULTIPLE-VALUE-CALL #'%TIME (%%TIME) ,@vars))
  238.      ) ; Diese Konstruktion verbraucht zur Laufzeit nur Stackplatz!
  239. ) )
  240. ;-------------------------------------------------------------------------------
  241. (defmacro with-input-from-string
  242.     ((var string &key (index nil sindex) (start '0 sstart) (end 'NIL send))
  243.      &body body &environment env)
  244.   (multiple-value-bind (body-rest declarations) (SYSTEM::PARSE-BODY body nil env)
  245.     (if declarations
  246.       (setq declarations (list (cons 'DECLARE declarations)))
  247.     )
  248.     `(LET ((,var (MAKE-STRING-INPUT-STREAM ,string 
  249.                    ,@(if (or sstart send)
  250.                        `(,start ,@(if send `(,end) '()))
  251.                        '()
  252.           ))     )   )
  253.        ,@declarations
  254.        (UNWIND-PROTECT
  255.          (PROGN ,@body-rest)
  256.          ,@(if sindex `((SETF ,index (SYSTEM::STRING-INPUT-STREAM-INDEX ,var))) '())
  257.          (CLOSE ,var)
  258.      ) )
  259. ) )
  260. ;-------------------------------------------------------------------------------
  261. (defmacro with-open-file ((stream &rest options) &body body &environment env)
  262.   (multiple-value-bind (body-rest declarations) (SYSTEM::PARSE-BODY body nil env)
  263.     (if declarations
  264.       (setq declarations (list (cons 'DECLARE declarations)))
  265.     )
  266.     `(LET ((,stream (OPEN ,@options)))
  267.        ,@declarations
  268.        (UNWIND-PROTECT
  269.          (MULTIPLE-VALUE-PROG1 (PROGN ,@body-rest)
  270.            (WHEN ,stream (CLOSE ,stream))
  271.          )
  272.          (WHEN ,stream (CLOSE ,stream :ABORT T))
  273.      ) )
  274. ) )
  275. ;-------------------------------------------------------------------------------
  276. (defmacro with-open-stream ((var stream) &body body &environment env)
  277.   (multiple-value-bind (body-rest declarations) (SYSTEM::PARSE-BODY body nil env)
  278.     (if declarations
  279.       (setq declarations (list (cons 'DECLARE declarations)))
  280.     )
  281.     `(LET ((,var ,stream))
  282.        ,@declarations
  283.        (UNWIND-PROTECT
  284.          (MULTIPLE-VALUE-PROG1 (PROGN ,@body-rest) (CLOSE ,var))
  285.          (CLOSE ,var :ABORT T)
  286.      ) )
  287. ) )
  288. ;-------------------------------------------------------------------------------
  289. (defmacro with-output-to-string
  290.     ((var &optional (string nil sstring)) &body body &environment env)
  291.   (multiple-value-bind (body-rest declarations) (SYSTEM::PARSE-BODY body nil env)
  292.     (if declarations
  293.       (setq declarations (list (cons 'DECLARE declarations)))
  294.     )
  295.     (if sstring
  296.       `(LET ((,var (SYS::MAKE-STRING-PUSH-STREAM ,string)))
  297.          ,@declarations
  298.          (UNWIND-PROTECT
  299.            (PROGN ,@body-rest)
  300.            (CLOSE ,var)
  301.        ) )
  302.       `(LET ((,var (MAKE-STRING-OUTPUT-STREAM)))
  303.          ,@declarations
  304.          (UNWIND-PROTECT
  305.            (PROGN ,@body-rest (GET-OUTPUT-STREAM-STRING ,var))
  306.            (CLOSE ,var)
  307.        ) )
  308. ) ) )
  309. ;-------------------------------------------------------------------------------
  310. (in-package "LISP")
  311. (export 'with-output-to-printer)
  312. (in-package "SYSTEM")
  313. (defmacro with-output-to-printer ((var) &body body &environment env)
  314.   #+ATARI
  315.     `(LET ((,var *PRINTER-OUTPUT*)) ,@body)
  316.   #-ATARI
  317.     (multiple-value-bind (body-rest declarations) (SYSTEM::PARSE-BODY body nil env)
  318.       (if declarations
  319.         (setq declarations (list (cons 'DECLARE declarations)))
  320.       )
  321.       #+VMS
  322.         (let ((filenamevar (gensym)))
  323.           `(LET (,filenamevar)
  324.              (WITH-OPEN-FILE (,var "SYS$SCRATCH:LISP_TO_PRINTER.TXT"
  325.                                    :DIRECTION :OUTPUT
  326.                                    :IF-EXISTS :NEW-VERSION
  327.                              )
  328.                ,@declarations
  329.                (SETQ ,filenamevar (TRUENAME ,var))
  330.                ,@body-rest
  331.              )
  332.              (SHELL (FORMAT NIL "PRINT /DELETE ~A" ,filenamevar))
  333.            )
  334.         )
  335.       #-VMS
  336.         `(LET ((,var #+UNIX (MAKE-PIPE-OUTPUT-STREAM "lpr")
  337.                      #-UNIX (SYS::MAKE-PRINTER-STREAM)
  338.               ))
  339.            ,@declarations
  340.            (UNWIND-PROTECT
  341.              (PROGN ,@body-rest)
  342.              (CLOSE ,var)
  343.          ) )
  344.     )
  345. )
  346. ;-------------------------------------------------------------------------------
  347.  
  348.